home *** CD-ROM | disk | FTP | other *** search
/ Transactor / Transactor_15_1987_Transactor_Publishing.d64 / eprom prg tester (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  1KB  |  47 lines
  1. 10 rem *********************************
  2. 20 rem *** eprom programmer tester *****
  3. 30 rem *** by tim bolbach  (1986)  *****
  4. 40 rem *********************************
  5. 50 n$(1)=" u1 port a":ad(1)=56832
  6. 60 n$(2)=" u1 port b":ad(2)=56833
  7. 70 n$(3)=" u1 port c":ad(3)=56834
  8. 80 n$(4)=" u2 port b":ad(4)=57089
  9. 90 for a=1 to 4:for t=0 to 7:read p(a,t+1):next t:next a
  10. 100 rem *** set all ports to write ***
  11. 110 poke56835,128
  12. 120 poke57091,128
  13. 130 rem *** menu select ***
  14. 140 print"[147]";
  15. 150 print"eprom programmer tester":print
  16. 160 print"----  menu ----  "
  17. 170 print
  18. 180 print" 1 - u1 port a"
  19. 190 print" 2 - u1 port b"
  20. 200 print" 3 - u1 port c"
  21. 210 print" 4 - u2 port b"
  22. 220 print:print:print"refer to schematic diagram for"
  23. 230 print"chip and port designations"
  24. 240 poke198,0:wait198,1:geta$
  25. 250 a=asc(a$)-48:if a>4 or a<1 then 240
  26. 260 print"[147]"
  27. 270 print"set voltmeter for 5 volts    [146]"
  28. 280 print"connect negative to pin #7   [146]"
  29. 290 print"connect positive to pin shown[146]"
  30. 300 print:print
  31. 310 printn$(a);"  address is ";ad(a)
  32. 320 print:print:print
  33. 330 for t=0 to 7
  34. 340 print" pin # ";p(a,t+1);tab(20);"bit";t
  35. 350 next t
  36. 360 print:print"common  is pin # 7"
  37. 370 print:print
  38. 380 input "bit #[160]to turn on (8=menu) ";b
  39. 390 ifb<0 or b>8 then 380
  40. 400 ifb=8 then 130
  41. 410 poke ad(a),2^b
  42. 420 goto 260
  43. 430 data 4,3,2,1,40,39,38,37
  44. 440 data 18,19,20,21,22,23,24,25
  45. 450 data 14,15,16,17,13,12,11,10
  46. 460 data 18,19,20,21,22,23,24,25
  47.